Auteur Topic: Aandrijving inbouwen in handdraaischijf  (gelezen 29122 keer)

0 leden en 1 gast bekijken dit topic.

Offline Rob

  • Forumbeheerder
  • Super Modelspoorder
  • *****
  • Berichten: 2.482
  • Thanked: 145 times
  • Geslacht: Man
  • Rob zegt: denk aan morgen, doe vandaag.
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #75 Gepost op: 16 februari 2022, 22:46:59 »
Hoi Bert,

Ha, het vragen(v)uurtje is aangebroken :).
De sketch vragen/aanpassingen laat ik even liggen; daar gaat je zoon mee aan de slag.

Over de analoge poorten: hier zitten AD converters op die een spanning van 0 tot 5V omzetten in een getal tussen 0 en 1023.
In mijn ervaring levert die een behoorlijk stabiele waarde.

Je kunt even een programma'tje schrijven de de analoge pin uitleest en op het computerscherm zet met de seriële monitor in de Arduino IDE (Serial.print) en Serial.println). Als je dan de knopjes op de 8-voudige spanningsdeler uitleest, zet je de grenswaarden er precies tussenin. Misschien is er ook wel iets dergelijks te vinden, bijvoorbeeld een programmatje dat de waarde van een potmeter op een analoge pin uitleest. Dat is feitelijk ook een spanningsdeler.

Rob
Ergens in (West) Duitsland tussen 1960 en 1970 | gelijkstroom analoog, met geluid | kleine vaste baan en uitbreiding met modulebaan.
Nu vooral bezig met van alles en nog wat...

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #76 Gepost op: 16 februari 2022, 22:51:37 »
Dank voor de tips Rob, ik ga eens wat experimenteren.

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #77 Gepost op: 17 februari 2022, 23:13:15 »
Hoi zet je de grenswaarden er precies tussenin.
Hoi Rob,
Ik las deze zin opnieuw, denk dat ik het nu pas begrijp…
Sketch van jou aangepast. Met kleine haperingen kan ik nu naar 10 posities bewegen.
TrackLeds is nog “wip”

Sketch geschreven om de knoppen uit te lezen, dat gaat perfect.
Ik veronderstelde dat ik die waarden moest gebruiken maar nu zie ik dat ik er juist tussenin moet gaan zitten.
Dus knoppen geven bijvoorbeeld de volgende waarden aan:
100, 300, 500 enz
De sketch dan:
0, 200, 400 enz
Goed begrepen?

Offline Rob

  • Forumbeheerder
  • Super Modelspoorder
  • *****
  • Berichten: 2.482
  • Thanked: 145 times
  • Geslacht: Man
  • Rob zegt: denk aan morgen, doe vandaag.
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #78 Gepost op: 18 februari 2022, 10:34:47 »
Hoi Bert,

Ik veronderstelde dat ik die waarden moest gebruiken maar nu zie ik dat ik er juist tussenin moet gaan zitten.
Dus knoppen geven bijvoorbeeld de volgende waarden aan:
100, 300, 500 enz
De sketch dan:
0, 200, 400 enz
Goed begrepen?

Precies. Met de grenswaarden er precies tussenin is enige "ruis" of onnauwkeurigheid op de spanningsdeler niet zo snel een probleem. Als je de waarde ongeveer uit kan lezen is het goed :)

Rob
Ergens in (West) Duitsland tussen 1960 en 1970 | gelijkstroom analoog, met geluid | kleine vaste baan en uitbreiding met modulebaan.
Nu vooral bezig met van alles en nog wat...

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #79 Gepost op: 18 februari 2022, 11:16:21 »
prima gelukt Rob!
Dit heb ik gebruikt voor het uitlezen:
void setup() {
  Serial.begin(9600);
  while(!Serial); // wait for Serial port to enumerate, need for Native USB based boards only
  Serial.println("starting test");
pinMode (A1, INPUT);
}

void loop()

Moest even zoeken naar de Arduino seriële monitor.
In het totaal een projectje waar ik veel van leer.

{
 
int x=analogRead(A1);
Serial.print ("Analog value: "); // put your main code here, to run repeatedly:
Serial.println (x);
delay (500);

}

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #80 Gepost op: 18 februari 2022, 11:19:19 »

prima gelukt Rob!
Dit heb ik gebruikt voor het uitlezen:
void setup() {
  Serial.begin(9600);
  while(!Serial); // wait for Serial port to enumerate, need for Native USB based boards only
  Serial.println("starting test");
pinMode (A1, INPUT);
}

void loop()


{
 
int x=analogRead(A1);
Serial.print ("Analog value: "); // put your main code here, to run repeatedly:
Serial.println (x);
delay (500);

}

Moest even zoeken naar de Arduino seriële monitor.
In het totaal een projectje waar ik veel van leer.

Hoop dat mijn zoon in het weekend de TrackLeds voor elkaar kan krijgen, hij heeft al een stuk gedaan, er zit nog een foutje in.
De led signalen wil ik ook gebruiken voor het openen van de ringloods deuren

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #81 Gepost op: 19 februari 2022, 13:37:08 »
mooie stap verder. Hij draait keurig naar 10 posities.
Sketch is klaar voorlopig.
De 4 trackleds geven nu de binaire code weer. Zodra ik de demultiplexer binnen heb kan ik daar Track1-track10 uithalen, max tot 16. Maar zien hoeveel tracks het uiteindelijk worden.
Tevens werkt het spersein. Die gaat eerst op rood (en wit uit) ff wachten, dan beweging, einde beweging weer een delay, dan rood uit/wit aan.

Wil de sketch best in de post zetten maar weet ff niet hoe Rob dat mooi doet in een venster?

In ieder geval is het schema voorlopig ook klaar:

Het lijkt heel wat maar valt reuze mee. Kom maar op met opmerkingen / vragen


Offline Rob

  • Forumbeheerder
  • Super Modelspoorder
  • *****
  • Berichten: 2.482
  • Thanked: 145 times
  • Geslacht: Man
  • Rob zegt: denk aan morgen, doe vandaag.
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #82 Gepost op: 19 februari 2022, 19:41:39 »
Hoi Bert,

Nou, je hebt het hele gebeuren een heel stuk verder ontwikkeld. Leuk!.

Als je de sketch neer wil zetten, gebruik dan code tags. Dat is vierkantehaak-"code"-vierkantehaak, de sketch, vierkantehaak-slash-"code"-vierkantehaak. Die tags worden ook gemaakt met het #-knopje als je een bericht aan het maken bent.


groet,
Rob
Ergens in (West) Duitsland tussen 1960 en 1970 | gelijkstroom analoog, met geluid | kleine vaste baan en uitbreiding met modulebaan.
Nu vooral bezig met van alles en nog wat...

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #83 Gepost op: 19 februari 2022, 20:00:13 »
Dank voor de opmerking Rob, het is erg leuk om te doen!
Er zullen nog wel wat puntjes op de i gezet worden. Een verbeteringspunt is nog het delay tussen het schakelen van de sperleds en start/einde beweging.
Iets wat ik nog wat belangrijker vind is " de kortste weg vinden" Nu draait ie vanuit 0 altijd linksom naar de grootste hoek, even ingesteld op 270 graden terwijl hij ook 90 rechtsom had gekund.
Ik weet even niet of jij dit erin had zitten en het hier verknoeid is?

De code kan nog wel wat opgeschoond worden. Bijvoorbeeld "TrackLed" past niet meer.

De sketch dan, hoop dat ik je goed begrepen heb:
/* Turntable control
 * =================
 * For a partial turntable. 4 tracks at  angles of 15, 20 and 15 degrees
 *
 * Beschrijving (NL)
 * Besturing voor een modelspoor segmentdraaischijf met 4 sporen.
 * De draaischijf wordt aangedreven met een stappenmotor.
 * Bediening met een '0-positie' sensor en 4 drukknoppen op een spanningsdeler
 * Terugmelding over 4 LEDs: een LED voor elk spoor.
 *
 * versie 2.0, 20 okt 2018
 */

/***** Import needed libraries ******/
#include <AccelStepper.h>

#define FULLSTEP 4
#define HALFSTEP 8


/***** Declare Pin Numbers *******/

// motor pins
#define motorPin1  2   // Blue   - 28BYJ48 pin 1
#define motorPin2  3   // Pink   - 28BYJ48 pin 2
#define motorPin3  4   // Yellow - 28BYJ48 pin 3
#define motorPin4  5   // Orange - 28BYJ48 pin 4

// sensor pins (analog)
#define startPin   8    // pin to detect turntable start position
#define buttonsPin A1   // analog pin to read buttons by Voltage divider

// led indicators pins
# define trackLed1 9    // led for track 1
# define trackLed2 10   // led for track 2
# define trackLed3 11   // led for track 3
# define trackLed4 12   // led for track 4

// spersein leds
# define sperledRed 6   // rode led spersein
# define sperledWit 7   // witte led spersein

#define ledpin     13   // LED on Arduino

/******* Definitions for turntable control ******/

// ---- Turntable ----
// Physical definitions
#define slack            9       // steps of slack in stepper motor axel from middle
#define initMove       -30       // steps to move at initialisation before sensor read
#define numberOfTracks  10       // number of tracks on turntable

// arrays below must correspond with number of tracks:
// positions for 10 turntable tracks (motor steps from 0) -> 1 omwenteling = ~ 26500 stappen.
int track[numberOfTracks]{-100, -2000, -3100, -4200, -5300, -6400, -7500, -13000, -15000, -17000};
int buttonBoundary[numberOfTracks]{1000, 900, 800, 700, 650, 550, 480, 380, 280, 180};

// Operational definitions
#define startTrack         0     // initial track to move to (after detecting 0-position sensor)
#define maxTurnSpeed       400.0 // maximum speed of stepper motor normal operation -> van 55 naar 400 =~ 60sec / omwenteling
#define startTurnSpeed     120.0 // start speed of stepper motor -> van 20 naar 120 verhoogd
#define turnAccelleration  46.0  // acceleration of stepper motor

// ---- Led display ----
unsigned long prevms = 0;        // blinking led milisecs last on/off
unsigned long curms = millis();  // blinking led milisecs now
const long blnkint = 250;        // blink interval in milliisec.


/******* Global variables ******/

// ---- Turntable variables ----
int currentTrack = 0;            // position after initialisation
int newTrack = 0;                // 1st position to move to after initialisation
int button = -1;                 // button pressed (0, 1 2 or 3, -1 is no button)

// ---- Led display variables ----
int blnk = HIGH;

/****** Objects *******/

// ---- Stepper motor object ----
AccelStepper stepper1(HALFSTEP, motorPin1, motorPin3, motorPin2, motorPin4);

// array of pins used to send out the binary-encoded track number
int ledPins[]{trackLed1, trackLed2, trackLed3, trackLed4};

/****** Functions ******/

#define ArrayCount(x) (sizeof(x) / sizeof(x[0]))

// ---- initialiation: 0-position detection ----
// Turntable initialisation after starting/resetting Arduino.
// It first moves the stepper motor counterclockwise (defined by initMove),
// and then moves the turntable clockwise slowly untill 0-positions is sensed
// on "startPin".
// Motor position "0"is set to the sensor position.
// Function returns "true" if sensor has been detected.
//
// Maximum steps is to find sensor: last track position + initial move steps.
// When 0 position is not sensed, function returns "false".
bool initTurntable() {
    bool succesfull = true;     // return parameter
    int x = 0;                  // step counter
    digitalWrite(ledpin, LOW);  // show initialisation ongoing on Arduino board

    // calculate total maximum number of steps (maxSteps) to find sensor:
    // the number of steps to position of last track, including slack and initial move
    int maxSteps = abs(track[numberOfTracks - 1]) + abs(initMove) + 2 * slack;  // sensor must be found in less steps

    // move  turntable into start / reset position

    stepper1.setMaxSpeed(10); // verhoogd van 1 naar 10
    stepper1.setAcceleration(500.0);
    stepper1.setSpeed(10);    // verhoogd van 1 naar 10
    // start with a move counterclockwise in case just beyond sensor...
    x = initMove;

    // now keep turning the table slowly until start point sensed
    do {
        stepper1.runToNewPosition(x);
        x++; //was x++; nu sneller naar 0 positie
    } while ((digitalRead(startPin) == LOW) && (x < maxSteps)); //run until sensor active, or max steps done (error)

    if (x < maxSteps) {                   // start position sensed. Intialise stepper position
        stepper1.setCurrentPosition(0);   // sensor position = 0
        digitalWrite(ledpin, HIGH);       // end of initialisation
    } else {                              // initialisation error
        succesfull = false;
    }
    stepper1.disableOutputs();            // Turn off stepper motor power
    return succesfull;
}

// ---- read button sensor ----
// function to get button from analog pin
// returns button 0-3 pressed.
// returns -1 if no button pressed
int getButtonPressed() {
    int r = analogRead(buttonsPin);
    int b = -1;
    if (r < buttonBoundary[0]) {    // a button was pressed
        delay(200);                 // wait for analog pin to stabalize
        r = analogRead(buttonsPin);

        // check which boundary value has been read on analog buttonPin
        if (r < buttonBoundary[0]) {
            b = numberOfTracks - 1; // check lat button to first
            while (r > buttonBoundary[b]) {
                b--;
            }
        }
    }
    return b;
}

// ---- turntable movement calculation ----
// function to calculate new position for turntable to move to
// input: new track number
// output: new stepper position with corrections mechanical inaccuracies
int calcNewPosition(int trk) {
    int pos = 0;                 // new stepper motor position
    int curTurnDirection = 0;    // current direction in Turntable = calculate for slack in movement

    // keep values last move before calculating new move
    currentTrack = newTrack;
    newTrack = trk;

    // Init new move
    // check direction for additional slack movement.
    // calculate new stepper position
    if (newTrack > currentTrack) {
        curTurnDirection = -1;                  // counterclockwise
    } else {
        curTurnDirection = 1;                   // clockwise
    }
    // calculate position to move to
    pos = track[newTrack];                      // bare track position
    pos = pos + (curTurnDirection * 2 * slack); // correction for slack
    return pos;
}

// ---- LED indiator function ----
// led on / of / blink function
// trackNumber: track number
// func:        0 = off, 1 = blink, 2 = on

void setLed(int trackNumber, int func) {
    if (func == 0) {
        writeLedPins(trackNumber, LOW);
    }
    if (func == 2) {
        writeLedPins(trackNumber, HIGH);
    }
    if (func == 1) {
        curms = millis();
        if (curms - prevms >= blnkint) {
            prevms = curms;
            if (blnk == HIGH) {
                blnk = LOW;
            } else {
                blnk = HIGH;
            }
            writeLedPins(trackNumber, blnk);
        }
    }
}

// Set led pins depending on the binary input in the `ledPins` array, at position `led`.
void writeLedPins(int trackNumber, int value) {
    //Serial.println();
    //Serial.print("Track: ");
    //Serial.println(trackNumber);

    // Loop over all led pins.
    for (int i = 0; i < ArrayCount(ledPins); ++i) {
        // If the bit for the current led pin is set, set the pin.
        digitalWrite(ledPins[i], trackNumber & (int) round(pow(2, i)) ? value : LOW);
        //Serial.print(trackNumber & (int) round(pow(2, i)) ? value : LOW);
    }
    //Serial.println();
}

void setSperSign(bool isWhite) {
    digitalWrite(sperledRed, isWhite ? LOW : HIGH);
    digitalWrite(sperledWit, isWhite ? HIGH : LOW);
}

/****** SETUP: RUNS ONCE ******/

void setup() {
    bool init = false;  // turntable intialisation status

    //Serial.begin(9600);

    int x = 0;
    // set the digital led pins as output and initialise values
    while (x < ArrayCount(ledPins)) {
        pinMode(ledPins[x], OUTPUT);
        analogWrite(ledPins[x], 255);
        digitalWrite(ledPins[x], LOW); // show initializing: all track leds off
        x++;
    }

    // show: initializing: Loop through all leds
    for (int i = 0; i < numberOfTracks; ++i) {
        writeLedPins(i, HIGH);
        delay(250);
    }
    writeLedPins(0, LOW);

    pinMode(ledpin, OUTPUT);
    digitalWrite(startPin, LOW);    // initialise startpin low. Default HIGH, aangepast ivm IR tunnel

    digitalWrite(buttonsPin, HIGH); // initialise button read

    // turntable initialisation: search for 0-position sensor
    init = initTurntable();         // initialise turntable.

    while (not init) {              // Find 0-position (sensor), false = 0-pos. not found
        digitalWrite(ledpin, HIGH); // Blink led indefenitely
        delay(100);
        digitalWrite(ledpin, LOW);
        delay(100);
    }

    // no error: setup turntable and led indicators for normal operation
    x = 0;
    while (x < ArrayCount(ledPins)) {  // switch off track leds
        digitalWrite(ledPins[x], LOW);
        x++;
    }

    // Setings for speed and accelaration during normal operation
    stepper1.setMaxSpeed(maxTurnSpeed);
    stepper1.setAcceleration(turnAccelleration);
    stepper1.setSpeed(startTurnSpeed);

    // move to initial track
    stepper1.moveTo(calcNewPosition(startTrack)); // move to new position in normal operation
    stepper1.runSpeed();

}//--(end setup )---


/****** LOOP: RUNS CONSTANTLY ******/

void loop() {
    stepper1.run();                      // operate the stepper motor

    // turntable stop
    if (stepper1.distanceToGo() == 0) {  // turntable at desired position
        stepper1.disableOutputs();       // turn stepper motor off (all pins low)
       
        setLed(newTrack, 2);             //turn on led for track positioned to

        button = getButtonPressed();                  // check if a button was pressed

        delay(250);
        setSperSign(true);
           
        if (button > -1 && button != newTrack) {      // button pressed for another track than positioned on
            setSperSign(false);
            delay(100);                              // Wacht een seconde na het spersignaal

            setLed(newTrack, 0);                      //turn off led for this track, we're moving away from it.
            stepper1.moveTo(calcNewPosition(button)); // calculate new stepper position and move to it.
        }
    }// turntable moving
    else {                                // turntable turning (moving to desired position)
        setLed(newTrack, 1);              // blink the LED for the track where turntable is moving to
    }
}//--(end main loop )---


//*********( THE END )***********



Offline Rob

  • Forumbeheerder
  • Super Modelspoorder
  • *****
  • Berichten: 2.482
  • Thanked: 145 times
  • Geslacht: Man
  • Rob zegt: denk aan morgen, doe vandaag.
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #84 Gepost op: 19 februari 2022, 20:15:13 »
Hoi Bert,

code is, net als een modelbaan, eigenlijk nooit echt af :)

Iets wat ik nog wat belangrijker vind is " de kortste weg vinden" Nu draait ie vanuit 0 altijd linksom naar de grootste hoek, even ingesteld op 270 graden terwijl hij ook 90 rechtsom had gekund.
Ik weet even niet of jij dit erin had zitten en het hier verknoeid is?
Je hebt niets verknoeid. Mijn draaischijf is een segmentdraaischijf, en draait niet helemaal rond (kan ook niet).



Dus was er geen kortste weg vraagstuk: die is altijd met de klok mee. De software heeft geen oplossing voor een probleem dat er nog niet was  ;)

Overigens heeft de Arduino ook wat flash geheugen. Die kun je gebruiken om de laatste positie op te slaan. De posite wordt dan onthouden als de Arduino uit gaat. En dit geheugen kun je bij het opstarten weer uitlezen om daarmee de snelste route naar de 0-positie te vinden.
Ik zou wel die 0-positie blijven zoeken, zodat elke keer weer vanuit een goede reset wordt gestart.

Rob
Ergens in (West) Duitsland tussen 1960 en 1970 | gelijkstroom analoog, met geluid | kleine vaste baan en uitbreiding met modulebaan.
Nu vooral bezig met van alles en nog wat...

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #85 Gepost op: 19 februari 2022, 20:20:53 »
Ah, goed te weten ;D
Kan zo maar zijn dat “we” het oplossen. Beter voor de arbeidsverhouding met het personeel ter plekke  :D.

Kan nu even niet verder, wachten op tante Ali.

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #86 Gepost op: 20 februari 2022, 21:42:32 »
Hoi Rob,
Ik had vanmorgen een ingeving en dacht " de kortste weg" makkelijk te kunnen oplossen:
   //if (newTrack > currentTrack) { // Rob's intitial statement
    if (newTrack > currentTrack && newTrack + currentTrack <-13250) { // shortest direction is chosen. 13250 equals 180 degrees turn
        curTurnDirection = -1;                  // counterclockwise
    } else {
        curTurnDirection = 1;                   // clockwise
Hij reageert hier niet op. Vervolgens jouw statement terug gezet en als test curTurnDirection de "-" verplaatst naar "else" Ook hierop reageert de stepper niet, het blijft zoals het is.

Ik duik er morgen verder in, anders zoon/IT-er wel maar wellicht zegt het jou direct iets?

Offline Rob

  • Forumbeheerder
  • Super Modelspoorder
  • *****
  • Berichten: 2.482
  • Thanked: 145 times
  • Geslacht: Man
  • Rob zegt: denk aan morgen, doe vandaag.
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #87 Gepost op: 21 februari 2022, 09:05:23 »
Hoi Bert,

Ah, het gaat om de kortste weg bij gewoon gebruik. Ik dacht alleen aan het begin...
Dat is wel even een uitdenkertje. Want je kunt natuurlijk ook meer dan 180 of zelfs 360 graden draaien. En dan wordt de logica heel anders: blijf je doortellen na 360 graden, of zet je deze weer op 0. Wat nu als je van 330 graden naar 30 (390) graden draait en zo voorts.
Daar heb ik ook geen snel antwoord op.

Succes,
Rob
Ergens in (West) Duitsland tussen 1960 en 1970 | gelijkstroom analoog, met geluid | kleine vaste baan en uitbreiding met modulebaan.
Nu vooral bezig met van alles en nog wat...

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #88 Gepost op: 21 februari 2022, 09:10:47 »
Hoi Rob,
ik hou wel van puzzels:)

Eerst maar even doorgronden waarom het omdraaien van de CurnTurn geen effect heeft, dan verder.

Wat hij namelijk in jouw sketch wel doet is de andere kant opdraaien indiendien hij van bv track 3 naar 4 was gegaan en dan weer terug moet.

Je gaat het vast horen

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #89 Gepost op: 3 maart 2022, 10:33:32 »
Spullen van tante Ali binnengekomen, kon ik mooi verder:



Hij loopt lekker rustig en stopt keurig telkens op dezelfde plek. Met de slackcompensatie zit het dus ook wel goed.

Met de brug zit het me nog niet lekker. C-rail op de brug staat voor geen meter. 2e hands K-rail gevonden, komt hoop ik morgen beter. Heb voorbeelden gezien met “parket” op de brug en eventueel op de stuurhut, denk dat ik dat ga doen.

Gisteren liep ik ook weer aan tegen het “zoeken naar de 0 positie aan. DomDom, had hem uitgezet net op de verkeerde positie, duurt een uurtje voordat hij met zoeken rond is.

Bedacht een alternatieve oplossing, werkt uitstekend:

1 schakelaar die ff het zoeken stop zet ( lichtsluis overrulen)
2 schakelaar die kiest tussen normale weerstandsbrug en een potmeter omzetten
3 extra positie instellen die bijna helemaal rond gaat.
Hij volgt dan keurig de stand van de potmeter. Draaien tot ie bij de juiste positie staat.
4 Arduino dan resetten en meteen schakelaar terug op weerstandsbrug.

Ga het schema hierop aanpassen

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #90 Gepost op: 3 maart 2022, 10:45:35 »
poging gedaan om een video te maken:


met nog een C-rail erop  ;D

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #91 Gepost op: 6 maart 2022, 12:41:04 »
Mooi stuk verder gekomen. Nu met Krail:)
Hekwerk en trappetje zijn ook klaar maar dat komt er later aan. Idem houten vlonders tot aan de spoorstaven.
Tevens de H- balken ter ondersteuning.

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #92 Gepost op: 11 maart 2022, 11:44:43 »
Stap verder:

Oplopende bodem uiteindelijk van witte klei gemaakt, gemengt met wat zwart acrylverf. In ieder geval alvast een basis voor verdere afwerking. Hij loopt soepel over de rails.

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #93 Gepost op: 11 maart 2022, 17:27:18 »

Offline Luud

  • Kruier
  • *
  • Berichten: 14
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #94 Gepost op: 11 maart 2022, 19:09:51 »
Mmoie stappen Bert, Gaaf om te zien..

Offline Rob

  • Forumbeheerder
  • Super Modelspoorder
  • *****
  • Berichten: 2.482
  • Thanked: 145 times
  • Geslacht: Man
  • Rob zegt: denk aan morgen, doe vandaag.
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #95 Gepost op: 13 maart 2022, 21:25:04 »
Dat ziet er allemaal goed uit, Bert.
Ik heb je filmpje even tussen [youtube] tags gezet. Kunnen we het hier meteen op het Forum bekijken.

Rob
Ergens in (West) Duitsland tussen 1960 en 1970 | gelijkstroom analoog, met geluid | kleine vaste baan en uitbreiding met modulebaan.
Nu vooral bezig met van alles en nog wat...

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #96 Gepost op: 13 maart 2022, 21:44:24 »
Dank Rob!
Ga ik dat de volgende keer ook zo doen

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #97 Gepost op: 15 maart 2022, 20:17:56 »
Stapje verder.
MDF rand vastgelijmd. Met een lintzaag uit een plaatje gehaald.
Binnenkort de brug spuiten in een soort legergroen.


Offline Pierre

  • Super Modelspoorder
  • ******
  • Berichten: 7.680
  • Thanked: 309 times
  • Geslacht: Man
  • Woonplaats: Den Haag (Loosduinen)
    • Station Hoogbaan
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #98 Gepost op: 16 maart 2022, 10:16:07 »
Mooie update weer Bert. De draaischijf loopt prachtig.;)
Groet Pierre.




Ik rommel wat met treintjes en bouwwerkjes in H0 (H0e) en zelfs een klein beetje in N    ;D
The following users thanked this post: Bert

Offline Bert

  • Stationchef
  • ***
  • Berichten: 168
  • Thanked: 7 times
  • Geslacht: Man
Re: Aandrijving inbouwen in handdraaischijf
« Reactie #99 Gepost op: 21 maart 2022, 17:38:59 »

Verf moet nog wat bijgewerkt worden.
Daarna de planken nog